NormNormalization of STLC
(* Chapter maintained by Andrew Tolmach *)
(* (Based on TAPL Ch. 12.) *)
Require Import Coq.Lists.List.
Import ListNotations.
Require Import SfLib.
Require Import Maps.
Require Import Smallstep.
Hint Constructors multi.
(This chapter is optional.)
In this chapter, we consider another fundamental theoretical property
of the simply typed lambda-calculus: the fact that the evaluation of a
well-typed program is guaranteed to halt in a finite number of
steps—-i.e., every well-typed term is normalizable.
Unlike the type-safety properties we have considered so far, the
normalization property does not extend to full-blown programming
languages, because these languages nearly always extend the simply
typed lambda-calculus with constructs, such as general recursion
(as we discussed in the MoreStlc chapter) or recursive types, that can
be used to write nonterminating programs. However, the issue of
normalization reappears at the level of types when we consider the
metatheory of polymorphic versions of the lambda calculus such as
F_omega: in this system, the language of types effectively contains a
copy of the simply typed lambda-calculus, and the termination of the
typechecking algorithm will hinge on the fact that a ``normalization''
operation on type expressions is guaranteed to terminate.
Another reason for studying normalization proofs is that they are some
of the most beautiful—-and mind-blowing—-mathematics to be found in
the type theory literature, often (as here) involving the fundamental
proof technique of logical relations.
The calculus we shall consider here is the simply typed
lambda-calculus over a single base type bool and with pairs. We'll
give full details of the development for the basic lambda-calculus
terms treating bool as an uninterpreted base type, and leave the
extension to the boolean operators and pairs to the reader. Even for
the base calculus, normalization is not entirely trivial to prove,
since each reduction of a term can duplicate redexes in subterms.
Exercise: 1 star
Where do we fail if we attempt to prove normalization by a straightforward induction on the size of a well-typed term?(* FILL IN HERE *)
☐
Language
Inductive ty : Type :=
| TBool : ty
| TArrow : ty → ty → ty
| TProd : ty → ty → ty
.
Inductive tm : Type :=
(* pure STLC *)
| tvar : id → tm
| tapp : tm → tm → tm
| tabs : id → ty → tm → tm
(* pairs *)
| tpair : tm → tm → tm
| tfst : tm → tm
| tsnd : tm → tm
(* booleans *)
| ttrue : tm
| tfalse : tm
| tif : tm → tm → tm → tm.
(* i.e., if t0 then t1 else t2 *)
Fixpoint subst (x:id) (s:tm) (t:tm) : tm :=
match t with
| tvar y ⇒ if beq_id x y then s else t
| tabs y T t1 ⇒ tabs y T (if beq_id x y then t1 else (subst x s t1))
| tapp t1 t2 ⇒ tapp (subst x s t1) (subst x s t2)
| tpair t1 t2 ⇒ tpair (subst x s t1) (subst x s t2)
| tfst t1 ⇒ tfst (subst x s t1)
| tsnd t1 ⇒ tsnd (subst x s t1)
| ttrue ⇒ ttrue
| tfalse ⇒ tfalse
| tif t0 t1 t2 ⇒ tif (subst x s t0) (subst x s t1) (subst x s t2)
end.
Notation "'[' x ':=' s ']' t" := (subst x s t) (at level 20).
Inductive value : tm → Prop :=
| v_abs : ∀x T11 t12,
value (tabs x T11 t12)
| v_pair : ∀v1 v2,
value v1 →
value v2 →
value (tpair v1 v2)
| v_true : value ttrue
| v_false : value tfalse
.
Hint Constructors value.
Reserved Notation "t1 '⇒' t2" (at level 40).
Inductive step : tm → tm → Prop :=
| ST_AppAbs : ∀x T11 t12 v2,
value v2 →
(tapp (tabs x T11 t12) v2) ⇒ [x:=v2]t12
| ST_App1 : ∀t1 t1' t2,
t1 ⇒ t1' →
(tapp t1 t2) ⇒ (tapp t1' t2)
| ST_App2 : ∀v1 t2 t2',
value v1 →
t2 ⇒ t2' →
(tapp v1 t2) ⇒ (tapp v1 t2')
(* pairs *)
| ST_Pair1 : ∀t1 t1' t2,
t1 ⇒ t1' →
(tpair t1 t2) ⇒ (tpair t1' t2)
| ST_Pair2 : ∀v1 t2 t2',
value v1 →
t2 ⇒ t2' →
(tpair v1 t2) ⇒ (tpair v1 t2')
| ST_Fst : ∀t1 t1',
t1 ⇒ t1' →
(tfst t1) ⇒ (tfst t1')
| ST_FstPair : ∀v1 v2,
value v1 →
value v2 →
(tfst (tpair v1 v2)) ⇒ v1
| ST_Snd : ∀t1 t1',
t1 ⇒ t1' →
(tsnd t1) ⇒ (tsnd t1')
| ST_SndPair : ∀v1 v2,
value v1 →
value v2 →
(tsnd (tpair v1 v2)) ⇒ v2
(* booleans *)
| ST_IfTrue : ∀t1 t2,
(tif ttrue t1 t2) ⇒ t1
| ST_IfFalse : ∀t1 t2,
(tif tfalse t1 t2) ⇒ t2
| ST_If : ∀t0 t0' t1 t2,
t0 ⇒ t0' →
(tif t0 t1 t2) ⇒ (tif t0' t1 t2)
where "t1 '⇒' t2" := (step t1 t2).
Notation multistep := (multi step).
Notation "t1 '⇒*' t2" := (multistep t1 t2) (at level 40).
Hint Constructors step.
Notation step_normal_form := (normal_form step).
Lemma value__normal : ∀t, value t → step_normal_form t.
Proof with eauto.
intros t H; induction H; intros [t' ST]; inversion ST...
Qed.
Definition context := partial_map ty.
Inductive has_type : context → tm → ty → Prop :=
(* Typing rules for proper terms *)
| T_Var : ∀Γ x T,
Γ x = Some T →
has_type Γ (tvar x) T
| T_Abs : ∀Γ x T11 T12 t12,
has_type (update Γ x T11) t12 T12 →
has_type Γ (tabs x T11 t12) (TArrow T11 T12)
| T_App : ∀T1 T2 Γ t1 t2,
has_type Γ t1 (TArrow T1 T2) →
has_type Γ t2 T1 →
has_type Γ (tapp t1 t2) T2
(* pairs *)
| T_Pair : ∀Γ t1 t2 T1 T2,
has_type Γ t1 T1 →
has_type Γ t2 T2 →
has_type Γ (tpair t1 t2) (TProd T1 T2)
| T_Fst : ∀Γ t T1 T2,
has_type Γ t (TProd T1 T2) →
has_type Γ (tfst t) T1
| T_Snd : ∀Γ t T1 T2,
has_type Γ t (TProd T1 T2) →
has_type Γ (tsnd t) T2
(* booleans *)
| T_True : ∀Γ,
has_type Γ ttrue TBool
| T_False : ∀Γ,
has_type Γ tfalse TBool
| T_If : ∀Γ t0 t1 t2 T,
has_type Γ t0 TBool →
has_type Γ t1 T →
has_type Γ t2 T →
has_type Γ (tif t0 t1 t2) T
.
Hint Constructors has_type.
Hint Extern 2 (has_type _ (tapp _ _) _) ⇒ eapply T_App; auto.
Hint Extern 2 (_ = _) ⇒ compute; reflexivity.
Inductive appears_free_in : id → tm → Prop :=
| afi_var : ∀x,
appears_free_in x (tvar x)
| afi_app1 : ∀x t1 t2,
appears_free_in x t1 → appears_free_in x (tapp t1 t2)
| afi_app2 : ∀x t1 t2,
appears_free_in x t2 → appears_free_in x (tapp t1 t2)
| afi_abs : ∀x y T11 t12,
y ≠ x →
appears_free_in x t12 →
appears_free_in x (tabs y T11 t12)
(* pairs *)
| afi_pair1 : ∀x t1 t2,
appears_free_in x t1 →
appears_free_in x (tpair t1 t2)
| afi_pair2 : ∀x t1 t2,
appears_free_in x t2 →
appears_free_in x (tpair t1 t2)
| afi_fst : ∀x t,
appears_free_in x t →
appears_free_in x (tfst t)
| afi_snd : ∀x t,
appears_free_in x t →
appears_free_in x (tsnd t)
(* booleans *)
| afi_if0 : ∀x t0 t1 t2,
appears_free_in x t0 →
appears_free_in x (tif t0 t1 t2)
| afi_if1 : ∀x t0 t1 t2,
appears_free_in x t1 →
appears_free_in x (tif t0 t1 t2)
| afi_if2 : ∀x t0 t1 t2,
appears_free_in x t2 →
appears_free_in x (tif t0 t1 t2)
.
Hint Constructors appears_free_in.
Definition closed (t:tm) :=
∀x, ¬ appears_free_in x t.
Lemma context_invariance : ∀Γ Γ' t S,
has_type Γ t S →
(∀x, appears_free_in x t → Γ x = Γ' x) →
has_type Γ' t S.
Proof with eauto.
intros. generalize dependent Γ'.
induction H;
intros Γ' Heqv...
- (* T_Var *)
apply T_Var... rewrite ← Heqv...
- (* T_Abs *)
apply T_Abs... apply IHhas_type. intros y Hafi.
unfold update, t_update. destruct (beq_idP x y)...
- (* T_Pair *)
apply T_Pair...
- (* T_If *)
eapply T_If...
Qed.
Lemma free_in_context : ∀x t T Γ,
appears_free_in x t →
has_type Γ t T →
∃T', Γ x = Some T'.
Proof with eauto.
intros x t T Γ Hafi Htyp.
induction Htyp; inversion Hafi; subst...
- (* T_Abs *)
destruct IHHtyp as [T' Hctx]... ∃T'.
unfold update, t_update in Hctx.
rewrite false_beq_id in Hctx...
Qed.
Corollary typable_empty__closed : ∀t T,
has_type empty t T →
closed t.
Proof.
intros. unfold closed. intros x H1.
destruct (free_in_context _ _ _ _ H1 H) as [T' C].
inversion C. Qed.
Lemma substitution_preserves_typing : ∀Γ x U v t S,
has_type (update Γ x U) t S →
has_type empty v U →
has_type Γ ([x:=v]t) S.
Proof with eauto.
(* Theorem: If Gamma,x:U |- t : S and empty |- v : U, then
Gamma |- (x:=vt) S. *)
intros Γ x U v t S Htypt Htypv.
generalize dependent Γ. generalize dependent S.
(* Proof: By induction on the term t. Most cases follow directly
from the IH, with the exception of tvar and tabs.
The former aren't automatic because we must reason about how the
variables interact. *)
induction t;
intros S Γ Htypt; simpl; inversion Htypt; subst...
- (* tvar *)
simpl. rename i into y.
(* If t = y, we know that
empty ⊢ v : U and
Γ,x:U ⊢ y : S
and, by inversion, update Γ x U y = Some S. We want to
show that Γ ⊢ [x:=v]y : S.
There are two cases to consider: either x=y or x≠y. *)
unfold update, t_update in H1.
destruct (beq_idP x y).
+ (* x=y *)
(* If x = y, then we know that U = S, and that [x:=v]y = v.
So what we really must show is that if empty ⊢ v : U then
Γ ⊢ v : U. We have already proven a more general version
of this theorem, called context invariance. *)
subst.
inversion H1; subst. clear H1.
eapply context_invariance...
intros x Hcontra.
destruct (free_in_context _ _ S empty Hcontra) as [T' HT']...
inversion HT'.
+ (* x<>y *)
(* If x ≠ y, then Γ y = Some S and the substitution has no
effect. We can show that Γ ⊢ y : S by T_Var. *)
apply T_Var...
- (* tabs *)
rename i into y. rename t into T11.
(* If t = tabs y T11 t0, then we know that
Γ,x:U ⊢ tabs y T11 t0 : T11→T12
Γ,x:U,y:T11 ⊢ t0 : T12
empty ⊢ v : U
As our IH, we know that forall S Gamma,
Γ,x:U ⊢ t0 : S → Γ ⊢ [x:=v]t0 S.
We can calculate that
x:=vt = tabs y T11 (if beq_id x y then t0 else x:=vt0)
And we must show that Γ ⊢ [x:=v]t : T11→T12. We know
we will do so using T_Abs, so it remains to be shown that:
Γ,y:T11 ⊢ if beq_id x y then t0 else [x:=v]t0 : T12
We consider two cases: x = y and x ≠ y.
*)
apply T_Abs...
destruct (beq_idP x y).
+ (* x=y *)
(* If x = y, then the substitution has no effect. Context
invariance shows that Γ,y:U,y:T11 and Γ,y:T11 are
equivalent. Since the former context shows that t0 : T12, so
does the latter. *)
eapply context_invariance...
subst.
intros x Hafi. unfold update, t_update.
destruct (beq_id y x)...
+ (* x<>y *)
(* If x ≠ y, then the IH and context invariance allow us to show that
Γ,x:U,y:T11 ⊢ t0 : T12 =>
Γ,y:T11,x:U ⊢ t0 : T12 =>
Γ,y:T11 ⊢ [x:=v]t0 : T12 *)
apply IHt. eapply context_invariance...
intros z Hafi. unfold update, t_update.
destruct (beq_idP y z)...
subst. rewrite false_beq_id...
Qed.
Theorem preservation : ∀t t' T,
has_type empty t T →
t ⇒ t' →
has_type empty t' T.
Proof with eauto.
intros t t' T HT.
(* Theorem: If empty ⊢ t : T and t ⇒ t', then empty ⊢ t' : T. *)
remember (@empty ty) as Γ. generalize dependent HeqGamma.
generalize dependent t'.
(* Proof: By induction on the given typing derivation. Many cases are
contradictory (T_Var, T_Abs). We show just the interesting ones. *)
induction HT;
intros t' HeqGamma HE; subst; inversion HE; subst...
- (* T_App *)
(* If the last rule used was T_App, then t = t1 t2, and three rules
could have been used to show t ⇒ t': ST_App1, ST_App2, and
ST_AppAbs. In the first two cases, the result follows directly from
the IH. *)
inversion HE; subst...
+ (* ST_AppAbs *)
(* For the third case, suppose
t1 = tabs x T11 t12
and
t2 = v2.
We must show that empty ⊢ [x:=v2]t12 : T2.
We know by assumption that
empty ⊢ tabs x T11 t12 : T1→T2
and by inversion
x:T1 ⊢ t12 : T2
We have already proven that substitution_preserves_typing and
empty ⊢ v2 : T1
by assumption, so we are done. *)
apply substitution_preserves_typing with T1...
inversion HT1...
- (* T_Fst *)
inversion HT...
- (* T_Snd *)
inversion HT...
Qed.
☐
Lemma step_deterministic :
deterministic step.
Proof with eauto.
unfold deterministic.
(* FILL IN HERE *) Admitted.
Normalization
A trivial fact:
Lemma value_halts : ∀v, value v → halts v.
Proof.
intros v H. unfold halts.
∃v. split.
apply multi_refl.
assumption.
Qed.
The key issue in the normalization proof (as in many proofs by
induction) is finding a strong enough induction hypothesis. To this
end, we begin by defining, for each type T, a set R_T of closed
terms of type T. We will specify these sets using a relation R
and write R T t when t is in R_T. (The sets R_T are sometimes
called saturated sets or reducibility candidates.)
Here is the definition of R for the base language:
This definition gives us the strengthened induction hypothesis that we
need. Our primary goal is to show that all programs —-i.e., all
closed terms of base type—-halt. But closed terms of base type can
contain subterms of functional type, so we need to know something
about these as well. Moreover, it is not enough to know that these
subterms halt, because the application of a normalized function to a
normalized argument involves a substitution, which may enable more
evaluation steps. So we need a stronger condition for terms of
functional type: not only should they halt themselves, but, when
applied to halting arguments, they should yield halting results.
The form of R is characteristic of the logical relations proof
technique. (Since we are just dealing with unary relations here, we
could perhaps more properly say logical properties.) If we want to
prove some property P of all closed terms of type A, we proceed by
proving, by induction on types, that all terms of type A possess
property P, all terms of type A→A preserve property P, all
terms of type (A→A)->(A→A) preserve the property of preserving
property P, and so on. We do this by defining a family of
properties, indexed by types. For the base type A, the property is
just P. For functional types, it says that the function should map
values satisfying the property at the input type to values satisfying
the property at the output type.
When we come to formalize the definition of R in Coq, we hit a
problem. The most obvious formulation would be as a parameterized
Inductive proposition like this:
Unfortunately, Coq rejects this definition because it violates the
strict positivity requirement for inductive definitions, which says
that the type being defined must not occur to the left of an arrow in
the type of a constructor argument. Here, it is the third argument to
R_arrow, namely (∀ s, R T1 s → R TS (tapp t s)), and
specifically the R T1 s part, that violates this rule. (The
outermost arrows separating the constructor arguments don't count when
applying this rule; otherwise we could never have genuinely inductive
properties at all!) The reason for the rule is that types defined
with non-positive recursion can be used to build non-terminating
functions, which as we know would be a disaster for Coq's logical
soundness. Even though the relation we want in this case might be
perfectly innocent, Coq still rejects it because it fails the
positivity test.
Fortunately, it turns out that we can define R using a
Fixpoint:
- R bool t iff t is a closed term of type bool and t halts in a value
- R (T1 → T2) t iff t is a closed term of type T1 → T2 and t halts in a value and for any term s such that R T1 s, we have R T2 (t s).
Inductive R : ty → tm → Prop :=
| R_bool : ∀b t, has_type empty t TBool →
halts t →
R TBool t
| R_arrow : ∀T1 T2 t, has_type empty t (TArrow T1 T2) →
halts t →
(∀s, R T1 s → R T2 (tapp t s)) →
R (TArrow T1 T2) t.
| R_bool : ∀b t, has_type empty t TBool →
halts t →
R TBool t
| R_arrow : ∀T1 T2 t, has_type empty t (TArrow T1 T2) →
halts t →
(∀s, R T1 s → R T2 (tapp t s)) →
R (TArrow T1 T2) t.
Fixpoint R (T:ty) (t:tm) {struct T} : Prop :=
has_type empty t T ∧ halts t ∧
(match T with
| TBool ⇒ True
| TArrow T1 T2 ⇒ (∀s, R T1 s → R T2 (tapp t s))
(* FILL IN HERE *)
| TProd T1 T2 ⇒ False (* ... and delete this line *)
end).
As immediate consequences of this definition, we have that every
element of every set R_T halts in a value and is closed with type
t :
Lemma R_halts : ∀{T} {t}, R T t → halts t.
Proof.
intros. destruct T; unfold R in H; inversion H; inversion H1; assumption.
Qed.
Lemma R_typable_empty : ∀{T} {t}, R T t → has_type empty t T.
Proof.
intros. destruct T; unfold R in H; inversion H; inversion H1; assumption.
Qed.
Now we proceed to show the main result, which is that every
well-typed term of type T is an element of R_T. Together with
R_halts, that will show that every well-typed term halts in a
value.
Membership in R_T is invariant under evaluation
Lemma step_preserves_halting : ∀t t', (t ⇒ t') → (halts t ↔ halts t').
Proof.
intros t t' ST. unfold halts.
split.
- (* -> *)
intros [t'' [STM V]].
inversion STM; subst.
exfalso. apply value__normal in V. unfold normal_form in V. apply V. ∃t'. auto.
rewrite (step_deterministic _ _ _ ST H). ∃t''. split; assumption.
- (* <- *)
intros [t'0 [STM V]].
∃t'0. split; eauto.
Qed.
Now the main lemma, which comes in two parts, one for each
direction. Each proceeds by induction on the structure of the type
T. In fact, this is where we make fundamental use of the
structure of types.
One requirement for staying in R_T is to stay in type T. In the
forward direction, we get this from ordinary type Preservation.
Lemma step_preserves_R : ∀T t t', (t ⇒ t') → R T t → R T t'.
Proof.
induction T; intros t t' E Rt; unfold R; fold R; unfold R in Rt; fold R in Rt;
destruct Rt as [typable_empty_t [halts_t RRt]].
(* TBool *)
split. eapply preservation; eauto.
split. apply (step_preserves_halting _ _ E); eauto.
auto.
(* TArrow *)
split. eapply preservation; eauto.
split. apply (step_preserves_halting _ _ E); eauto.
intros.
eapply IHT2.
apply ST_App1. apply E.
apply RRt; auto.
(* FILL IN HERE *) Admitted.
The generalization to multiple steps is trivial:
Lemma multistep_preserves_R : ∀T t t',
(t ⇒* t') → R T t → R T t'.
Proof.
intros T t t' STM; induction STM; intros.
assumption.
apply IHSTM. eapply step_preserves_R. apply H. assumption.
Qed.
In the reverse direction, we must add the fact that t has type
T before stepping as an additional hypothesis.
Lemma step_preserves_R' : ∀T t t',
has_type empty t T → (t ⇒ t') → R T t' → R T t.
Proof.
(* FILL IN HERE *) Admitted.
Lemma multistep_preserves_R' : ∀T t t',
has_type empty t T → (t ⇒* t') → R T t' → R T t.
Proof.
intros T t t' HT STM.
induction STM; intros.
assumption.
eapply step_preserves_R'. assumption. apply H. apply IHSTM.
eapply preservation; eauto. auto.
Qed.
Closed instances of terms of type T belong to R_T
Multisubstitutions, multi-extensions, and instantiations
Definition env := list (id × tm).
Fixpoint msubst (ss:env) (t:tm) {struct ss} : tm :=
match ss with
| nil ⇒ t
| ((x,s)::ss') ⇒ msubst ss' ([x:=s]t)
end.
We need similar machinery to talk about repeated extension of a
typing context using a list of (identifier, type) pairs, which we
call a type assignment.
Definition tass := list (id × ty).
Fixpoint mupdate (Γ : context) (xts : tass) :=
match xts with
| nil ⇒ Γ
| ((x,v)::xts') ⇒ update (mupdate Γ xts') x v
end.
We will need some simple operations that work uniformly on
environments and type assigments
Fixpoint lookup {X:Set} (k : id) (l : list (id × X)) {struct l} : option X :=
match l with
| nil ⇒ None
| (j,x) :: l' ⇒
if beq_id j k then Some x else lookup k l'
end.
Fixpoint drop {X:Set} (n:id) (nxs:list (id × X)) {struct nxs} : list (id × X) :=
match nxs with
| nil ⇒ nil
| ((n',x)::nxs') ⇒ if beq_id n' n then drop n nxs' else (n',x)::(drop n nxs')
end.
An instantiation combines a type assignment and a value
environment with the same domains, where corresponding elements are
in R
Inductive instantiation : tass → env → Prop :=
| V_nil : instantiation nil nil
| V_cons : ∀x T v c e, value v → R T v → instantiation c e → instantiation ((x,T)::c) ((x,v)::e).
We now proceed to prove various properties of these definitions.
Lemma vacuous_substitution : ∀ t x,
¬ appears_free_in x t →
∀t', [x:=t']t = t.
Proof with eauto.
(* FILL IN HERE *) Admitted.
Lemma subst_closed: ∀t,
closed t →
∀x t', [x:=t']t = t.
Proof.
intros. apply vacuous_substitution. apply H. Qed.
Lemma subst_not_afi : ∀t x v, closed v → ¬ appears_free_in x ([x:=v]t).
Proof with eauto. (* rather slow this way *)
unfold closed, not.
induction t; intros x v P A; simpl in A.
- (* tvar *)
destruct (beq_idP x i)...
inversion A; subst. auto.
- (* tapp *)
inversion A; subst...
- (* tabs *)
destruct (beq_idP x i)...
+ inversion A; subst...
+ inversion A; subst...
- (* tpair *)
inversion A; subst...
- (* tfst *)
inversion A; subst...
- (* tsnd *)
inversion A; subst...
- (* ttrue *)
inversion A.
- (* tfalse *)
inversion A.
- (* tif *)
inversion A; subst...
Qed.
Lemma duplicate_subst : ∀t' x t v,
closed v → [x:=t]([x:=v]t') = [x:=v]t'.
Proof.
intros. eapply vacuous_substitution. apply subst_not_afi. auto.
Qed.
Lemma swap_subst : ∀t x x1 v v1, x ≠ x1 → closed v → closed v1 →
[x1:=v1]([x:=v]t) = [x:=v]([x1:=v1]t).
Proof with eauto.
induction t; intros; simpl.
- (* tvar *)
destruct (beq_idP x i); destruct (beq_idP x1 i).
+ subst. exfalso...
+ subst. simpl. rewrite ← beq_id_refl. apply subst_closed...
+ subst. simpl. rewrite ← beq_id_refl. rewrite subst_closed...
+ simpl. rewrite false_beq_id... rewrite false_beq_id...
(* FILL IN HERE *) Admitted.
Lemma msubst_closed: ∀t, closed t → ∀ss, msubst ss t = t.
Proof.
induction ss.
reflexivity.
destruct a. simpl. rewrite subst_closed; assumption.
Qed.
Closed environments are those that contain only closed terms.
Fixpoint closed_env (env:env) {struct env} :=
match env with
| nil ⇒ True
| (x,t)::env' ⇒ closed t ∧ closed_env env'
end.
Next come a series of lemmas charcterizing how msubst of closed terms
distributes over subst and over each term form
Lemma subst_msubst: ∀env x v t, closed v → closed_env env →
msubst env ([x:=v]t) = [x:=v](msubst (drop x env) t).
Proof.
induction env0; intros; auto.
destruct a. simpl.
inversion H0. fold closed_env in H2.
destruct (beq_idP i x).
- subst. rewrite duplicate_subst; auto.
- simpl. rewrite swap_subst; eauto.
Qed.
Lemma msubst_var: ∀ss x, closed_env ss →
msubst ss (tvar x) =
match lookup x ss with
| Some t ⇒ t
| None ⇒ tvar x
end.
Proof.
induction ss; intros.
reflexivity.
destruct a.
simpl. destruct (beq_id i x).
apply msubst_closed. inversion H; auto.
apply IHss. inversion H; auto.
Qed.
Lemma msubst_abs: ∀ss x T t,
msubst ss (tabs x T t) = tabs x T (msubst (drop x ss) t).
Proof.
induction ss; intros.
reflexivity.
destruct a.
simpl. destruct (beq_id i x); simpl; auto.
Qed.
Lemma msubst_app : ∀ss t1 t2, msubst ss (tapp t1 t2) = tapp (msubst ss t1) (msubst ss t2).
Proof.
induction ss; intros.
reflexivity.
destruct a.
simpl. rewrite ← IHss. auto.
Qed.
You'll need similar functions for the other term constructors.
(* FILL IN HERE *)
Properties of multi-extensions
Lemma mupdate_lookup : ∀(c : tass) (x:id), lookup x c = (mupdate empty c) x.
Proof.
induction c; intros.
auto.
destruct a. unfold lookup, mupdate, update, t_update. destruct (beq_id i x); auto.
Qed.
Lemma mupdate_drop : ∀(c: tass) Γ x x',
mupdate Γ (drop x c) x' = if beq_id x x' then Γ x' else mupdate Γ c x'.
Proof.
induction c; intros.
- destruct (beq_idP x x'); auto.
- destruct a. simpl.
destruct (beq_idP i x).
+ subst. rewrite IHc.
unfold update, t_update. destruct (beq_idP x x'); auto.
+ simpl. unfold update, t_update. destruct (beq_idP i x'); auto.
subst. rewrite false_beq_id; congruence.
Qed.
Lemma instantiation_domains_match: ∀{c} {e},
instantiation c e → ∀{x} {T}, lookup x c = Some T → ∃t, lookup x e = Some t.
Proof.
intros c e V. induction V; intros x0 T0 C.
solve by inversion .
simpl in ×.
destruct (beq_id x x0); eauto.
Qed.
Lemma instantiation_env_closed : ∀c e, instantiation c e → closed_env e.
Proof.
intros c e V; induction V; intros.
econstructor.
unfold closed_env. fold closed_env.
split. eapply typable_empty__closed. eapply R_typable_empty. eauto.
auto.
Qed.
Lemma instantiation_R : ∀c e, instantiation c e →
∀x t T, lookup x c = Some T →
lookup x e = Some t → R T t.
Proof.
intros c e V. induction V; intros x' t' T' G E.
solve by inversion.
unfold lookup in ×. destruct (beq_id x x').
inversion G; inversion E; subst. auto.
eauto.
Qed.
Lemma instantiation_drop : ∀c env,
instantiation c env → ∀x, instantiation (drop x c) (drop x env).
Proof.
intros c e V. induction V.
intros. simpl. constructor.
intros. unfold drop. destruct (beq_id x x0); auto. constructor; eauto.
Qed.
Lemma multistep_App2 : ∀v t t',
value v → (t ⇒* t') → (tapp v t) ⇒* (tapp v t').
Proof.
intros v t t' V STM. induction STM.
apply multi_refl.
eapply multi_step.
apply ST_App2; eauto. auto.
Qed.
(* FILL IN HERE *)
The R Lemma.
Lemma msubst_preserves_typing : ∀c e,
instantiation c e →
∀Γ t S, has_type (mupdate Γ c) t S →
has_type Γ (msubst e t) S.
Proof.
induction 1; intros.
simpl in H. simpl. auto.
simpl in H2. simpl.
apply IHinstantiation.
eapply substitution_preserves_typing; eauto.
apply (R_typable_empty H0).
Qed.
And at long last, the main lemma.
Lemma msubst_R : ∀c env t T,
has_type (mupdate empty c) t T → instantiation c env → R T (msubst env t).
Proof.
intros c env0 t T HT V.
generalize dependent env0.
(* We need to generalize the hypothesis a bit before setting up the induction. *)
remember (mupdate empty c) as Γ.
assert (∀x, Γ x = lookup x c).
intros. rewrite HeqGamma. rewrite mupdate_lookup. auto.
clear HeqGamma.
generalize dependent c.
induction HT; intros.
- (* T_Var *)
rewrite H0 in H. destruct (instantiation_domains_match V H) as [t P].
eapply instantiation_R; eauto.
rewrite msubst_var. rewrite P. auto. eapply instantiation_env_closed; eauto.
- (* T_Abs *)
rewrite msubst_abs.
(* We'll need variants of the following fact several times, so its simplest to
establish it just once. *)
assert (WT: has_type empty (tabs x T11 (msubst (drop x env0) t12)) (TArrow T11 T12)).
{ eapply T_Abs. eapply msubst_preserves_typing.
{ eapply instantiation_drop; eauto. }
eapply context_invariance.
{ apply HT. }
intros.
unfold update, t_update. rewrite mupdate_drop. destruct (beq_idP x x0).
+ auto.
+ rewrite H.
clear - c n. induction c.
simpl. rewrite false_beq_id; auto.
simpl. destruct a. unfold update, t_update.
destruct (beq_id i x0); auto. }
unfold R. fold R. split.
auto.
split. apply value_halts. apply v_abs.
intros.
destruct (R_halts H0) as [v [P Q]].
pose proof (multistep_preserves_R _ _ _ P H0).
apply multistep_preserves_R' with (msubst ((x,v)::env0) t12).
eapply T_App. eauto.
apply R_typable_empty; auto.
eapply multi_trans. eapply multistep_App2; eauto.
eapply multi_R.
simpl. rewrite subst_msubst.
eapply ST_AppAbs; eauto.
eapply typable_empty__closed.
apply (R_typable_empty H1).
eapply instantiation_env_closed; eauto.
eapply (IHHT ((x,T11)::c)).
intros. unfold update, t_update, lookup. destruct (beq_id x x0); auto.
constructor; auto.
- (* T_App *)
rewrite msubst_app.
destruct (IHHT1 c H env0 V) as [_ [_ P1]].
pose proof (IHHT2 c H env0 V) as P2. fold R in P1. auto.
(* FILL IN HERE *) Admitted.
Theorem normalization : ∀t T, has_type empty t T → halts t.
Proof.
intros.
replace t with (msubst nil t) by reflexivity.
apply (@R_halts T).
apply (msubst_R nil); eauto.
eapply V_nil.
Qed.